arsd.pixmaprecorder

Pixmap Recorder is an auxiliary library for rendering video files from Pixmap frames by piping them to FFmpeg.

Members
Detailed Description

Tips and tricks
Examples

Getting started

Meta

Source

Members

Classes

PixmapRecorder class PixmapRecorder: Video file encoder

Piping frame data into an independent copy of FFmpeg enables this library to be used with a wide range of versions of said third-party program and (hopefully) helps to reduce the potential for breaking changes.

It also allows end-users to upgrade their possibilities by swapping the accompanying copy FFmpeg.

This could be useful in cases where software distributors can only provide limited functionality in their bundled binaries because of legal requirements like patent licenses. Keep in mind, support for more formats can be added to FFmpeg by linking it against external libraries; such can also come with additional distribution requirements that must be considered. These things might be perceived as extra burdens and can make their inclusion a matter of viability for distributors.

Tips and tricks

The FFmpeg binary to be used can be specified by the optional constructor parameter ffmpegExecutablePath.

It defaults to ffmpeg; this will trigger the usual lookup procedures of the system the application runs on. On POSIX this usually means searching for FFmpeg in the directories specified by the environment variable PATH. On Windows it will also look for an executable file with that name in the current working directory.

The value of the outputFormat parameter of various constructor overloads is passed to FFmpeg via the -f (“format”) option.

Run ffmpeg -formats to get a list of available formats.

To pass additional options to FFmpeg, use the additional-output-args property.

Combining this module with Pixmap Presenter is really straightforward.

In the most simplistic case, set up a PixmapRecorder before running the presenter. Then call pixmapRecorder.record(presenter.framebuffer)

at the end of the drawing callback in the eventloop.

auto recorder = new PixmapRecorder(60, /* … */);
scope(exit) {
	const recorderStatus = recorder.stopRecording();
}

return presenter.eventLoop(delegate() {
	// […]
	recorder.record(presenter.framebuffer);
	return LoopCtrl.redrawIn(16);
});

To use this module with arsd.color (which includes the image file loading functionality provided by other arsd modules), convert the TrueColorImage or MemoryImage to a Pixmap first by calling Pixmap.fromTrueColorImage()

or Pixmap.fromMemoryImage()

respectively.

Examples

Getting started

Install FFmpeg (the CLI version).
- Debian derivatives (with FFmpeg in their repos): apt install ffmpeg
- Homebew: brew install ffmpeg
- Chocolatey: choco install ffmpeg
- Links to pre-built binaries can be found on <https://ffmpeg.org/download.html>.
Determine where you’ve installed FFmpeg to. Ideally, it’s somewhere within “PATH” so it can be run from the command-line by just doing ffmpeg. Otherwise, you’ll need the specific path to the executable to pass it to the constructor of PixmapRecorder.

import arsd.pixmaprecorder;
import arsd.pixmappaint;

/++
	This demo renders a 1280×720 video at 30 FPS
	fading from white (#FFF) to blue (#00F).
 +/
int main() {
	// Instantiate a recorder.
	auto recorder = new PixmapRecorder(
		30,        // Video framerate [=FPS]
		"out.mkv", // Output path to write the video file to.
	);

	// We will use this framebuffer later on to provide image data
	// to the encoder.
	auto frame = Pixmap(1280, 720);

	for (int light = 0xFF; light >= 0; --light) {
		auto color = Color(light, light, 0xFF);
		frame.clear(color);

		// Record the current frame.
		// The video resolution to use is derived from the first frame.
		recorder.put(frame);
	}

	// End and finalize the recording process.
	return recorder.stopRecording();
}